xScaled.mp

verbatimtex
%&latex
\documentclass{article}
\newcommand{\fett}{\sffamily\bfseries}
\begin{document}
etex

u:=25;                    % 25 = 25bp = 25 PostScript points = 30/72 in
wi:=10;                   % width  in units u   
he:=7;                    % height in units u
hoehe:=he*u;              % height
breite:=wi*u;             % width
path p[], q[], r[];
picture pic;
transform t, T;
t:=identity scaled u;
T:=identity xscaled 4;
bboxmargin:=3;

beginfig(1)
  z0=(1.0, 1) transformed t;
  z1=(2,   4) transformed t;
  z2=(1.0, 4) transformed t;
  z3=(1.4, 3) transformed t;       % label
  
  p0:=z0{1,4}..z1{up}..{down}z2--cycle;
  q0:=(x0, 0)--(x0, hoehe);
  r0:=(x1, 0)--(x1, hoehe);
  
    p1:=p0 transformed T;
    q1:=q0 transformed T;
    r1:=r0 transformed T;

  % --- Grid ---
  for i=0 upto he:
    draw (0, i*u)--(breite, i*u) withcolor .7white;
  endfor
  for j=0 upto wi:
    draw (j*u, 0)--(j*u, hoehe) withcolor .7white;
  endfor
  % --- End Grid ---
  
  draw (0, 0)--(breite, 0)--(breite, hoehe)--(0, hoehe)--cycle;
  
  for i=0 upto 1:    
    fill p[i] withcolor .9white;
    pickup pencircle scaled .5;
    draw q[i] withcolor red;
    draw r[i] withcolor blue;
    pickup pencircle scaled 2;
    draw p[i];
  endfor
  
  label(btex $\mathcal{F}$ etex, z3);
  label(btex $\mathcal{F}'$ etex, z3 transformed T);
  
  if false:
    label(btex $\mathcal{F}_2$ etex, z3 transformed T2);
    label(btex $\mathcal{F}_3$ etex, z3 transformed T3);
  fi
    
  pic:=\thelabel(btex \fett T := identity xscaled 4 
                     etex, (.5breite, hoehe-1.1u));
		     
  unfill bbox pic;
  draw pic;
  pickup pencircle scaled .5;
  draw bbox pic;		     
endfig;

end